% lu_spu Uppercase forms special to Lushootseed font

cmchar "The letter Schwa";
newchar(Schwa,11u#,cap_height#,0);
italcorr .5[bar_height#,x_height#]*slant+.5min(curve#-1.5u#,0);
adjust_fit(if monospace: .25u#,.5u# else: 0,0 fi);
numeric left_curve,right_curve;
left_curve=right_curve+6stem_corr=cap_curve if not serifs: -3stem_corr fi;
if right_curve<tiny.breadth: right_curve:=tiny.breadth; fi
if left_curve<tiny.breadth: left_curve:=tiny.breadth; fi
pickup tiny.nib; pos1(right_curve,0);
pos2(cap_hair,90); pos3(left_curve,180);
y1=good.y .5[bar_height,x_height]; top y2r=h+vround 1.5oo; y0l=bot y1;
rt x1r=hround min(w-.5u,w-u+.5right_curve);
lft x3r=hround max(.5u,1.25u-.5left_curve); x2=.5w+.25u;
{{interim superness:=more_super;
 filldraw stroke super_arc.e(1,2)}};  % right bowl
y3=.5[y2,y4]; bot y4r=-oo; x4=x2+.25u;
if serifs: pos4(vair',270); pos5(hair,360);
 y5=max(good.y(.35x_height-.9),y4l+vair); x5r=x1r;
 (x,y4l)=whatever[z4r,z5]; x4l:=min(x,x4l+.5u);
 filldraw stroke pulled_arc.e(2,3) & pulled_arc.e(3,4)
  ...{x5-x4,5(y5-y4)}z5e; % left bowl, arc, and terminal
else: pos4(vair,270);
 filldraw stroke super_arc.e(2,3) & super_arc.e(3,4);  % left bowl and arc
 pickup fine.nib; pos4'(vair,270); z4=z4';
 pos5(.5[vair,flare],275); rt x5r=hround(w-.6u);
 y5r=good.y(y5r+1/3x_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
 filldraw stroke term.e(4',5,right,1,4); fi  % terminal
path testpath; testpath=super_arc.r(2,3) & super_arc.r(3,4);
y1'r=y0r=y0l+1.2[thin_join,vair]; y1'l=y0l; x1'l=x1'r=x1;
forsuffixes $=l,r:
 x0$=xpart(((0,y0$)--(x1,y0$)) intersectionpoint testpath); endfor
fill stroke z0e--z1'e;  % crossbar
x100=.5w; y100=.5h; flip(100);
z4.X=z4 rotatedaround(z100,180);
z2.X=z2 rotatedaround(z100,180);
penlabels(2.X,4.X); 
pairequate(lca,z2.X);
pairequate(tca,z4.X);
 pairequate(tra,tca); %top right accentpoint
 pairequate(tla,tca); %top left accentpoint
 pairequate(lla,lca); %low left accentpoint
 pairequate(lra,lca); %low right accentpoint
endchar;

cmchar "Root sign";
newchar(Root_sign,8.5u#,body_height#,paren_depth#-rule_thickness#);
 adjust_fit(0,-letter_fit#); pickup rule.nib;
 w':=7u;
 x1=good.x 1/9w'; x2=good.x .65w'; bot y1=-.5d; bot y2=asc_height;
 draw z1--z2;  % diagonal
 pickup crisp.nib; 
 if monospace: pos3(rule_thickness,0);
 else: pos3(.7max(curve,rule_thickness),0);
 fi
 x3l=1.5[x2,x1]; y3=.5[y1,y2];
 pos4(rule_thickness,0); x4=x1; bot y4=-.5d;
 pos5(vair,-45); x5l=good.x(x3l-u); z5l=whatever[z3r,z2];
 z6=z5r+whatever*(z2-z3r)=whatever[z3l,z4l];
 z7=whatever[z1,z2]=z3r+whatever*(z4l-z3l);
 filldraw z5r--z6--z4l--z4--z7--z3r--z5l--cycle;  % left diagonal and serif
x8=x2+2u; y8=y2;
pickup rule.nib;
draw z2--z8;
picture V; transform t; t=identity shifted(2.5u,0);
V=currentpicture transformed t; currentpicture:=V;
% penlabels(1,2,3,4,5,6,7,8); 
endchar;   

cmchar "crossed Lambda";
newchar(cross_Lambda,12u#,cap_height#,0);
adjust_fit(cap_serif_fit#,cap_serif_fit#);
numeric left_stem,outer_jut,alpha;
left_stem=cap_hair if hefty: -3stem_corr fi;
outer_jut=.7cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.5u; y1=y4=0;
x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h-.5slab;
alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
penpos3(alpha*cap_stem,0); penpos4(alpha*cap_stem,0);
z0=whatever[z1r,z2r]=whatever[z3l,z4l];
if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
  fill z0+.5right{down}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
    --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
    ...{up}z0+.5left--cycle; % left and right diagonals
else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
    --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
%
%  cross
%
pickup crisp.nib; pos98(slab,90); pos99(hair,0);
top y98r=h; x98=x2; 
rt x99r=hround(w-.65u); y99=good.y(y98l-beak)-eps;
arm(98,99,g,beak_darkness,0.7beak_jut);  % right arm and beak
pos100(hair,180); x100=w-x99; y100=y99;
arm(98,100,h,beak_darkness,-.7beak_jut);  % left arm and beak
%
if serifs: numeric inner_jut; pickup tiny.nib;
 prime_points_inside(1,2); prime_points_inside(4,3);
 if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
 else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
 dish_serif(1',2,a,1/2,outer_jut,b,.6,inner_jut)(dark);  % left serif
 dish_serif(4',3,c,1/2,inner_jut,d,1/3,outer_jut); fi  % right serif
penlabels(0,1,2,3,4,5,6,99,100); 
 pairequate(tca,z98);  %top center accentpoint
 pairassign(lca,.5w,0);  %low center accentpoint
 pairequate(tra,tca); %top right accentpoint
 pairequate(tla,tca); %top left accentpoint
 pairequate(lla,z1); %low left accentpoint
 pairequate(lra,z4); %low right accentpoint
endchar;

cmchar "serifed glottal stop";
newchar(Glottal_stop,8.5u#,cap_height#,0);
italcorr .8asc_height#*slant;
adjust_fit(0,0);
numeric bot_width;
%bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: 2hair fi;
bot_width= if hefty: stem else: .275(stem+cap_stem) fi;
%if serifs: bot_width:=1.5bot_width; fi
pickup fine.nib; pos2(vair,90); pos3(curve,0);
pos4(vair,-90); 
if hefty: pos5(bot_width,0) else: pos5(.92bot_width,0) fi; %pos5(.75bot_width,0) fi;
if hefty: pos6(bot_width,0) else: pos6(bot_width,0) fi; %pos6(.85bot_width,0) fi;
pos7(bot_width,0) ;
x7=.5w; bot y7=0;
x2=x4=x5=x6=x7; rt x3r=hround(w-u); y6=.375x_height;
if monospace: top y2r=h else: top y2r=h+oo fi; 
y3=.75[y6,y2]; y4=.5[y6,y2]; y5=.1[y6,y2];
{{interim superness:=more_super;
filldraw stroke pulled_super_arc.e(2,3)(superpull)
 & subpath (0,1) of super_arc.e(3,4) .. z5e---z6e\\}};  % arc and stem
filldraw stroke z6e---z7e;
if serifs: pos1(hair,180); pos0(flare,180);
 lft x1r=hround u; y1=y3; bulb(2,1,0);  % bulb
 dish_serif(7,6,q,1/3,jut,p,1/3,jut);
else: pos1(Vround 5/7[vair,flare],110);
 lft x1r=hround u; top y1r=vround .9[y6,top y2r];
 filldraw stroke term.e(2,1,left,1,4); fi  % terminal
penlabels(0,1,2,3,4,5,6,7,8); 
 pairequate(tca,z2);  %top center accentpoint
 pairequate(lca,z7);  %low center accentpoint
 pairequate(tra,tca); %top right accentpoint
 pairequate(tla,tca); %top left accentpoint
 pairequate(lla,lca); %low left accentpoint
 pairequate(lra,lca); %low right accentpoint
endchar;

% cmchar "crossed_L";
newchar(crossed_L,11u#-width_adj#,cap_height#,0);
adjust_fit(u#+cap_serif_fit#,0);
pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
filldraw stroke z1e--z2e; % stem
pickup crisp.nib; pos3(slab,-90); pos4(hair,0);
bot y3r=0; x3=x2; y4=y3l+7/6beak+eps; rt x4r=hround(w-.75u);
arm(3,4,e,1.2beak_darkness,beak_jut);  % lower arm and beak
if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,1.25cap_jut);  % upper serif
 nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
pairequate(tca,z1);  %top center accentpoint
if serifs: pairassign(lca,x.e2,0);  %low center accentpoint
else: pairassign(lca,.5x3+.5x4,0);  %low center accentpoint
fi
pairequate(tra,tca); %top right accentpoint
pairequate(tla,tca); %top left accentpoint
pairequate(lla,z2); %low left accentpoint
if serifs: pairequate(lra,z.e0); %low right accentpoint
else: pairequate(lra,z4); %low right accentpoint
fi
x7=x1; y7=.5(x_height+bar_height);
cross_for_lz(7,q);
math_fit(0,u#); penlabels(1,2,3,4); endchar;

% cmchar "belted L";
newchar(belted_L,11u#-width_adj#,cap_height#,0);
adjust_fit(u#+cap_serif_fit#,0);
pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
filldraw stroke z1e--z2e; % stem
pickup crisp.nib; pos3(slab,-90); pos4(hair,0);
bot y3r=0; x3=x2; y4=y3l+7/6beak+eps; rt x4r=hround(w-.75u);
arm(3,4,e,1.2beak_darkness,beak_jut);  % lower arm and beak
if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,1.25cap_jut);  % upper serif
 nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
pairequate(tca,z1);  %top center accentpoint
if serifs: pairassign(lca,x.e2,0);  %low center accentpoint
else: pairassign(lca,.5x3+.5x4,0);  %low center accentpoint
fi
pairequate(tra,tca); %top right accentpoint
pairequate(tla,tca); %top left accentpoint
pairequate(lla,z2); %low left accentpoint
if serifs: pairequate(lra,z.e0); %low right accentpoint
else: pairequate(lra,z4); %low right accentpoint
fi
x55=x1; y55=.6h; y56=y57=y55; x56=x55-3u; x57=x55+3u;
pos55(cap_stem,0); pos56(vair,180); pos57(slab,340);
filldraw stroke z55e{up}...{down}z56e...{(2,1)}z57e;
math_fit(0,u#); penlabels(1,2,3,4); endchar;

% cmchar "tilde-crossed L";
newchar(tildcross_L,11u#-width_adj#,cap_height#,0);
adjust_fit(u#+cap_serif_fit#,0);
pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
filldraw stroke z1e--z2e; % stem
pickup crisp.nib; pos3(slab,-90); pos4(hair,0);
bot y3r=0; x3=x2; y4=y3l+7/6beak+eps; rt x4r=hround(w-.75u);
arm(3,4,e,1.2beak_darkness,beak_jut);  % lower arm and beak
if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,1.25cap_jut);  % upper serif
 nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
pairequate(tca,z1);  %top center accentpoint
if serifs: pairassign(lca,x.e2,0);  %low center accentpoint
else: pairassign(lca,.5x3+.5x4,0);  %low center accentpoint
fi
pairequate(tra,tca); %top right accentpoint
pairequate(tla,tca); %top left accentpoint
pairequate(lla,z2); %low left accentpoint
if serifs: pairequate(lra,z.e0); %low right accentpoint
else: pairequate(lra,z4); %low right accentpoint
fi
x13=x1; y13=.55asc_height;
tilde_accent(13,q,x_height-cap_height);
math_fit(0,u#); penlabels(1,2,3,4); endchar;

cmchar "The letter Yogh";
newchar(Yogh,12u#,cap_height#,desc_depth#);
italcorr cap_height#*slant-.5u#;
adjust_fit(0,0);
numeric arm_thickness[],z_stem;
if hefty: arm_thickness1=Vround(slab-vair_corr); arm_thickness2=slab;
 z_stem=.8[vair,cap_stem];
else: arm_thickness1=slab; arm_thickness2=vround(slab+vair_corr);
 z_stem=.8[vair,cap_stem]; fi
pickup tiny.nib; x3l=w-x1r=w-x2r; lft x3l=hround u; x4=x3+4u;
top y1=h; y2=min(y1,h-2/3arm_thickness1);
bot y4=1.2bar_height; y3=max(y4,y4+2/3arm_thickness2);
numeric alpha; alpha=diag_ratio(1,z_stem-tiny,y2-y3,x2r-x3l);
penpos1(alpha*(z_stem-tiny),0); penpos2(alpha*(z_stem-tiny),0);
penpos3(alpha*(z_stem-tiny),0); penpos4(alpha*(z_stem-tiny),0);
pair delta; delta=penoffset z3-z2 of currentpen;
fill top lft z1l--z2l+delta---lft z4l..bot z4l
 ---bot rt z4r---z2r-delta..rt z2r---rt z1r..top z1r
 ---cycle;  % diagonal
pickup crisp.nib; pos5(arm_thickness1,90); pos6(hair,180);
top y5r=h; x5=x1; lft x6r=hround 2.25u; y6=good.y(y5l-beak)-eps;
arm(5,6,a,beak_darkness**.8,-.4beak_jut);  % upper arm and beak
pos7(arm_thickness2,-90); pos8(hair,0);
bot y7r=0; x7=x4; rt x8r=hround(w-.9u); y8=good.y(y7l+1.2beak)+eps;
bot_thickness:=max(fine.breadth,vround (slab-vair_corr));
mid_thickness:=max(fine.breadth,vround 2/3vair);
bot y28=-desc_depth; x28=.45w;
y27=.5[y4,y28]; rt x27r=rt x1r; 
pickup fine.nib;
pos22(mid_thickness,90); lft x22l=lft x4l; y22=y4;
pos27(cap_curve,0); pos28(bot_thickness,-90);
if serifs: numeric bulb_diam[];
 if monospace: bulb_diam2:=flare+cap_stem-stem else: bulb_diam2:=.85flare+cap_stem-stem fi;
 pos30(bulb_diam2,-180-.5angle(x1-x4,y1-y4)); pos29(cap_hair,-180);
 lft x30r=hround .75u; y30=0; %y30=-.5bulb_diam2; 
else:  pos29(bot_thickness,angle(-2u,-h));
 lft x29r=hround .75u; top y29l= -o;
 y29r:=good.y y29r-eps; x29l:=good.x x29l;
z30=z29; pos30(bot_thickness,angle(-2u,-h));
fi  % lower terminal
filldraw stroke pulled_super_arc.e(22,27)(.5superpull)
 & pulled_super_arc.e(27,28)(.5superpull) & pulled_super_arc.e(28,30)(.5superpull);
math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8); endchar;

cmchar "The letter Eng";
newchar(Eng,12u#,cap_height#,desc_depth#);
italcorr .9cap_height#*slant-serif_fit#+.5stem#-2u#;
adjust_fit(serif_fit#+stem_shift#+.75jut#,serif_fit#-stem_shift#);
pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
numeric shaved_stem; shaved_stem=hround(cap_stem-2stem_corr);
pos1'(shaved_stem,0); pos2'(shaved_stem,0); pos3(cap_stem,0);
lft x1l=hround(2.5u-.5cap_stem); x1l=x1'l=x2l=x2'l; x3=w-x1;
top y1=h+min(oo,serif_drop); bot y2=0; y1=y1'; y2=y2';
filldraw stroke z1'e--z2'e;  % left stem
caph_stroke(2,a,3,4);  % arch and right stem
if serifs: sloped_serif.l(1',2',b,1/3,cap_jut,serif_drop); % upper left serif
 numeric inner_jut; pickup tiny.nib;
 if rt x2r+cap_jut+.5u+1<=lft x4l-cap_jut: inner_jut=cap_jut;
 else: rt x2r+cap_jut+.5u+1=lft x4l-inner_jut; fi
 dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut); % lower left serif
 fi 
x22=x4; bot y22=-1/3d; pos22(cap_stem',0);
filldraw stroke z4e--z22e;
if serifs:  pickup tiny.nib; pos55(vair,-90); pos66(cap_hair,-180); pos77(flare,-180);
 x55=.5[x22,x66r]; bot y55r=-d-oo; y66-.5flare=-.88d;
 if monospace: lft x66r=4.75u else: z66r=z77r; rt x77l=floor 5.5u fi;
 (x,y55r)=whatever[z55l,z22l]; x55r:=max(x,.5[x66r,x55]);
 filldraw stroke z22e{down}...z55e{left};  bulb(55,66,77); % arc and bulb
else: pickup fine.nib; pos22'(cap_stem',0); z22'=z22;
 pos66(.2[vair,cap_stem'],-90); pos77(vair,-90);
 lft x77r=hround 3.5u; bot y77r=vround 5/6(-d-oo);
 (x,y77l)=whatever[z77r,z3]; x77l:=x;
 z55r=z22'r; (x22'l,y55l)=whatever[z77l,z55r]; x55l=x22'l; y55=y55r;
 x66r=.5[x77r,x55r]; x66l:=.5[x77l,x55l]; bot y66r=-d-oo;
 filldraw stroke z22'e..{down}z55e & super_arc.e(55,66)
  & z66e{left}..z77e; fi  % arc and terminal
pairequate(tca,z.a1);  %top center accentpoint
if serifs: pairequate(lca,z55);
else: pairequate(lca,z66);  %low center accentpoint
fi
pairequate(tra,tca); %top right accentpoint
pairequate(tla,tca); %top left accentpoint
pairequate(lla,lca); %low left accentpoint
pairequate(lra,lca); %low right accentpoint
endchar;

cmchar "center dot";
numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
define_whole_blacker_pixels(dot_diam);
newchar(center_dot,5u#,.75x_height#+.5dot_diam#,0);
adjust_fit(0,0); pickup fine.nib;
pos1(dot_diam,0); pos2(dot_diam,90);
lft x1l=hround(.5w-.5dot_diam); bot y2l=.75x_height-.5dot_diam; 
z1=z2; dot(1,2);  % dot
penlabels(1,2); endchar;

cmchar "seriffed pharyngeal stop";
newchar(Pharyng,8.5u#,cap_height#,0);
italcorr .8asc_height#*slant;
adjust_fit(0,0); slantswitch;
numeric bot_width;
bot_width= if hefty: stem else: .275(stem+cap_stem) fi;
%bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: 2hair fi;
%if serifs: bot_width:=1.5bot_width; fi
pickup fine.nib; pos2(vair,90); pos3(curve,0);
pos4(vair,-90); 
if hefty: pos5(bot_width,0) else: pos5(.92bot_width,0) fi;
if hefty: pos6(bot_width,0) else: pos6(bot_width,0) fi;
pos7(bot_width,0) ;
x7=.5w; bot y7=0;
x2=x4=x5=x6=x7; rt x3r=hround(w-u); y6=.375x_height;
if monospace: top y2r=h else: top y2r=h+oo fi; 
y3=.75[y6,y2]; y4=.5[y6,y2]; y5=.1[y6,y2];
{{interim superness:=more_super;
filldraw stroke pulled_super_arc.e(2,3)(superpull)
 & subpath (0,1) of super_arc.e(3,4) .. z5e---z6e\\}};  % arc and stem
filldraw stroke z6e---z7e;
if serifs: pos1(hair,180); pos0(flare,180);
 lft x1r=hround u; y1=y3; bulb(2,1,0);  % bulb
 dish_serif(7,6,q,1/3,jut,p,1/3,jut);
else: pos1(Vround 5/7[vair,flare],110);
 lft x1r=hround u; top y1r=vround .9[y6,top y2r];
 filldraw stroke term.e(2,1,left,1,4); fi  % terminal
mirror(.5w);
penlabels(0,1,2,3,4,5,6,7,8);
pairassign(tca,.5w,h);  %top center accentpoint
pairassign(lca,.5w,0);  %low center accentpoint
pairequate(tra,tca); %top right accentpoint
pairequate(tla,tca); %top left accentpoint
pairequate(lla,lca); %low left accentpoint
pairequate(lra,lca); %low right accentpoint
endchar;