% ortest.mf -- Oriya characters under design
% Copyright 1996, 1998 Jeroen Hellingman
%
% History:
%   03-MAY-1998 Last edit (Jeroen Hellingman)

endinput;

picture sub_dda_picture;
picture sup_dda_picture;

beginchar(c_dda, 25uw#+rm#, 25uh#, 0uh#); "Oriya letter dda";
  z11 = (9uw, 13uh);
  z12 = (good.x 4uw, 6uh);
  z13 = (.5[x12,x14], -overshoot);
  z14 = (good.x 20uw, 6uh);
  z15 = .5[z17,z18];
  z16 = z17 - (1uw, 2uh);
  z17 = (11uw, 8uh);
  z18 = (17uw, 15uh);
  z19 = z18 + (1uw, 2uh);
  z1 = (6.5uw, 11uh);
  x4 = 25uw;
  define_new_outer_circle;

  path dda_bar;
  path dda_curve;
  path dda_circle;
  dda_bar := z16..z17---z18..z19;
  dda_curve := z11{curl0}..z12{down}..z13{right}..z14{up}..z15;
  dda_circle := new_outer_circle_path;

  % subscribed ga:
  transform sub;
  sub := identity scaled 15/25 shifted (8uw, -9uh);
  pickup barpen;
  draw dda_bar transformed sub;
  drawdot(z16 transformed sub);
  drawdot(z19 transformed sub);
  pickup curvepen;
  draw dda_curve transformed sub;
  drawdot(z11 transformed sub);
  draw dda_circle transformed sub;
  drawdot(z5 transformed sub);
  currentpicture := currentpicture + currentpicture + currentpicture;
  unfill (dda_circle--cycle) transformed sub;
  sub_dda_picture := currentpicture;
  clearit;
  
  % the superior dda
  transform super;
  super := identity scaled 20/25 shifted (0, 5uh);
  pickup barpen;
  draw dda_bar transformed super;
  drawdot(z16 transformed super);
  drawdot(z19 transformed super);
  pickup curvepen;
  draw dda_curve transformed super;
  drawdot(z11 transformed super);
  draw dda_circle transformed super;
  drawdot(z5 transformed super);
  cullit; sup_dda_picture := currentpicture;
  clearit;

  % normal dda:
  pickup barpen;
  draw dda_bar;
  drawdot(z16);
  drawdot(z19);
  pickup curvepen;
  draw dda_curve;
  drawdot(z11);
  penlabels(11,12,13,14,15,16,17,18,19);
  cullit; savepicture := currentpicture;

  draw_new_outer_circle;
endchar;

beginchar(c_d_ga, 23uw#+rm#, 25uh#, 10uh#); "Oriya conjunct dd+dda";
  currentpicture := sup_dda_picture + sub_dda_picture;
endchar;


end.



endinput;

picture sup_da_picture;

beginchar(c_da, 23uw#+rm#, 25uh#, 0uh#); "Oriya letter da";
  pickup curvepen;
  z11 = (17uw, 0uh);
  z12 = (x11, 13uh);
  z13 = (7uw, 14uh);
  z14 = (3.5uw, 8uh);
  z15 = (10uw, 2uh);
  z16 = (x11, 6uh);
  z1 = (4.0uw, 11uh);
  x4 = 23uw;
  define_new_outer_circle;
  
  path da_bar;
  path da_curve;
  path da_circle;
  da_bar := z11---z12;
  da_curve := z13..z14{down}..z15{right}..{curl0}z16;
  da_circle := new_outer_circle_path;
  
  % the superior da
  transform super;
  super := identity scaled 20/25 shifted (0, 5uh);
  pickup barpen;
  draw da_bar transformed super;
  drawdot(z11 transformed super);
  drawdot(z12 transformed super);
  pickup curvepen;
  draw da_curve transformed super;
  draw da_circle transformed super;
  drawdot(z5 transformed super);
  drawdot(z13 transformed super);
  cullit; sup_da_picture := currentpicture;
  clearit;

  % the normal da
  pickup barpen;
  draw da_bar;
  drawdot(z11);
  drawdot(z12);
  pickup curvepen;
  draw da_curve;
  drawdot(z13);
  penlabels(11,12,13,14,15,16);
  cullit; savepicture := currentpicture;

  draw_new_outer_circle;
endchar;

picture sub_ga_picture;

beginchar(c_ga, 24uw#+rb#+rm#, 25uh#, 0uh#); "Oriya letter ga";
  z1 = (7.5uw, 9uh);
  z2 = (6uw, 5uh);
  z3 = (11.5uw, -overshoot);
  z4 = (17uw, 5uh);
  z5 = (12uw, 10uh);
  z6 = (6uw, 9uh);
  z7 = (0uw, 16uh);
  z8 = (11uw, h+overshoot);
  z9 = (24uw, h - joint);
  z10 = (x9, h);
  z11 = (x9, 0);

  path ga_curve;
  path ga_bar;
  ga_curve := z1{curl0}..z2{down}..z3{right}..z4{up}..z5{left}..z6{left}..
        z7{up}..z8{right}..{curl0}z9;
  ga_bar := z10--z11;

  % subscribed ga:
  transform sub;
  sub := identity scaled 15/25 shifted (8uw, -9uh);
  pickup curvepen;
  draw ga_curve transformed sub;
  drawdot(z9 transformed sub);
  pickup barpen;
  draw ga_bar transformed sub;
  drawdot(z10 transformed sub);
  drawdot(z11 transformed sub);
  currentpicture := currentpicture + currentpicture + currentpicture;
  unfill (z6{left}..z7{up}..z8{right}..{curl0}z9--z11--cycle) transformed sub;
  sub_ga_picture := currentpicture;
  clearit;

  % normal ga:
  pickup curvepen;
  draw ga_curve;
  drawdot(z9);
  pickup barpen;
  draw ga_bar;
  drawdot(z10);
  drawdot(z11);
  penlabels(1,2,3,4,5,6,7,8,9,10,11);
  savepicture := currentpicture;
endchar;

beginchar(c_d_ga, 22uw#+rm#, 25uh#, 5uh#); "Oriya conjunct d+ga";
  currentpicture := sup_da_picture + sub_ga_picture shifted (-1uw, 1uh);
endchar;

end.

% end of ortest.mf