!-----------------------------------LZDCMP.CLD------------------------------------
!
! Command language description for DECOMPRESS
!

MODULE lz_dcl_table

DEFINE VERB		DECOMPRESS

IMAGE 			LZW_DIR:LZDCMP.EXE

PARAMETER P1,				! Input file
	LABEL=INPUT
	PROMPT="Input file",
	VALUE (REQUIRED, TYPE=$FILE, LIST)

PARAMETER P2,				! Output file
	LABEL=OUTPUT
	PROMPT="Output file",
	VALUE (TYPE=$FILE)

QUALIFIER BITS,				! /BITS=<value>
	NONNEGATABLE,
	PLACEMENT=GLOBAL,
	VALUE(TYPE=$NUMBER)

QUALIFIER DELETE,
	NEGATABLE,
	PLACEMENT=GLOBAL

QUALIFIER IGNORE,			! /IGNORE=(OWNER,PROTECTION,...)
	NONNEGATABLE,
	PLACEMENT=GLOBAL,
	VALUE(TYPE=IGNORE_KEYWORDS,LIST)

QUALIFIER IMPORT,			! /IMPORT=(VMS UNIX BLOCK ENDMARKER)
        LABEL=EXPORT,
	NONNEGATABLE,			! Only /IMPORT=(UNIX, NOHEADER)
	PLACEMENT=GLOBAL,		! is meaningful.
	VALUE(TYPE=IMPORT_KEYWORDS, LIST),
	DISALLOW (VMS AND UNIX)
	DISALLOW (BLOCK AND NEG HEADER)
	DISALLOW (VMS AND NEG BLOCK)
	DISALLOW (VMS AND NEG HEADER)
	DISALLOW (VMS AND NEG ENDMARKER)
        DISALLOW (INTERCHANGE AND NEG VMS)

QUALIFIER LOG,
	NEGATABLE,
	PLACEMENT=GLOBAL

QUALIFIER METHOD,			! /METHOD=LZ
	NONNEGATABLE,
	PLACEMENT=GLOBAL,
	VALUE(TYPE=METHOD_KEYWORDS)

QUALIFIER SHOW,				! /SHOW=(PROGRESS, STATISTICS, DEBUG)
	NEGATABLE,
	PLACEMENT=GLOBAL,
	VALUE(TYPE=SHOW_KEYWORDS, LIST)

QUALIFIER MODE,				! /MODE=(TEXT | BINARY | STREAM | DELTA)
	NONNEGATABLE,
	PLACEMENT=GLOBAL,
	VALUE(TYPE=MODE_KEYWORDS, LIST),
	DISALLOW ANY2(TEXT, BINARY, STREAM)

DEFINE TYPE IMPORT_KEYWORDS
	KEYWORD VMS, DEFAULT
	KEYWORD UNIX,
	KEYWORD BLOCK, NEGATABLE
	KEYWORD HEADER, NEGATABLE
	KEYWORD ENDMARKER, NEGATABLE
        KEYWORD INTERCHANGE, NEGATABLE

DEFINE TYPE METHOD_KEYWORDS
	KEYWORD	LZ, DEFAULT

DEFINE TYPE MODE_KEYWORDS
	KEYWORD	TEXT, DEFAULT
	KEYWORD BINARY,
	KEYWORD STREAM,
	KEYWORD DELTA

DEFINE TYPE SHOW_KEYWORDS
	KEYWORD PROGRESS, NEGATABLE
	KEYWORD STATISTICS, NEGATABLE
	KEYWORD FDL, NEGATABLE
	KEYWORD DEBUG, NEGATABLE
	KEYWORD DEBUG_SERIOUS, NEGATABLE
	KEYWORD DEBUG_IO, NEGATABLE
	KEYWORD ALL			! Actually, all but debug

DEFINE TYPE IGNORE_KEYWORDS
        KEYWORD MT_BLOCK_SIZE, NEGATABLE
        KEYWORD MT_PROTECTION, NEGATABLE
        KEYWORD MT, NEGATABLE
        KEYWORD MAXIMIZE_VERSION, NEGATABLE
        KEYWORD OWNER, NEGATABLE
        KEYWORD PROTECTION, NEGATABLE
        KEYWORD ALL

SYNONYM UNCOMPRESS

SYNONYM LZDCMP

SYNONYM LZD